Andreas Kappes dann bleibt dir nur der Vorschlag mit Base64 zu arbeiten. Siehe folgenden Beitrag von Uwe:

https://forum.ninox.de/t/h7h0j1j/bilder-innerhalb-ninox-kopieren

Ich habe das bisher nicht genutzt. Aber ich vermute, dass er sich da nur auf eine Datenbank bezieht. Man müsste das also etwas anpassen, um es in eine zweite Datenbank in einem anderen Team zu schieben.

Aber wenn Du sagst, dass der Arbeitsspeicher beim Tablet in die Knie geht, dann bin ich da bei Christoph. Wenn Du Ansichten hast, wo viele Berechnungen stattfinden, kann das eher die Ursache sein. Die Dateien sollten eigentlich auf dem lokalen Speicher landen und nicht im Arbeitsspeicher.

Dafür müsste man aber wissen, was genau nicht funktioniert und wann das Problem auftritt.

Andreas Kappes 

das Erstellen von Records sollte das kleinste Problem sein. Hier ein Beispiel, wie ich Urlaubsanträge zwischen zwei Apps hin- und her schicke. In dem Beispiel wird ein Urlaubsantrag in App A erstellt und in App B zur Freigabe ein Record erstellt.

let settings := record(Einstellungen,1);
let myKey := settings.'Ninox API Key';
let dbTeam := settings.'Team ID Personal Datenbank';
let dbDatenbank := settings.'Datenbank ID Personal';
let myURL := "https://api.ninoxdb.de/v1/teams/" + dbTeam + "/databases/" + dbDatenbank +
    "/tables/F/records";
let employee := first((select Mitarbeiter where 'Ninox-Nutzer' = user()).ID);
let myTyp := Typ;
let myVon := Von;
let myBis := Bis;
let myGrund := 'Begründung';
let myVertretung := text(Vertretung);
let myID := number(this);
let body := [{
            fields: {
                'Status:': "2",
                Abwesenheitsart: myTyp,
                Von: myVon,
                Bis: myBis,
                Beschreibung: myGrund,
                Vertretung: myVertretung,
                AntragID: myID,
                Mitarbeiter: employee
            }
        }];
let auth := {
        Authorization: "Bearer " + myKey,
        'Content-Type': "application/json"
    };
let response := do as server
        http("POST", myURL, auth, body)
    end;
Response := formatJSON(response);
for i in parseJSON(text(response.result)) do
    AntragID := number(i.id)
end;
Status := 2

Das sind jetzt nur reine Daten. Aber mit Base64 sollte das ähnlich sein. Du musst nur die TeamId entsprechend anpassen.