Was hat es mit der zweiten Zeitangabe ( - 16.45 ) auf sich?

Es ist nicht so trivial. Ich habe mal eine Datenbank 069_ZEITINTERVALL ins Webinar Team geladen. Falls du dort noch nicht angemeldet bist, hier die Formel für ein Berechnungsfeld:

----

let DATUM1:=date(start(Termin));

let DATUM2:=today();

if DATUM1 = null or DATUM2 = null then
""
else
let D1 := if DATUM1 > DATUM2 then DATUM2 else DATUM1 end;
let D2 := if DATUM1 > DATUM2 then DATUM1 else DATUM2 end;
let DD := if day(D2) >= day(D1) then
day(D2) - day(D1)
else
day(date(year(D1), month(D1) + 1, 1) - 1) - day(D1) + day(D2)
end;
let MM := if month(D1) <= month(D2) then
month(D2) - month(D1)
else
12 - month(D1) + month(D2)
end;
let MMM := if day(D2) >= day(D1) then
MM
else
if MM = 0 then 11 else MM - 1 end
end;
let YY := if month(D2) > month(D1) then
year(D2) - year(D1)
else
if month(D2) < month(D1) then
year(D2) - year(D1) - 1
else
if day(D1) <= day(D2) then
year(D2) - year(D1)
else
year(D2) - year(D1) - 1
end
end
end;
if DATUM1 = null then
""
else
if YY = 0 then
""
else
if YY = 1 then
YY + " Jahr" + if MMM = 0 and DD = 0 then "" else ", " end
else
YY + " Jahre" + if MMM = 0 and DD = 0 then "" else ", " end
end
end + if MMM = 0 then
""
else
if MMM = 1 then
MMM + " Monat" + if DD = 0 then "" else ", " end
else
MMM + " Monate" + if DD = 0 then "" else ", " end
end
end + if DD = 0 then
""
else
if DD = 1 then DD + " Tag" else DD + " Tage" end
end
end
end

----

Leo