Hey Ich hab gesehen, dass es hier im Forum mit GPT Ninox-Scripten etwas mau ist.
Das würde ich doch gern ändern. Hier ein Snippet zum arbeiten mit den chat/completions Endpunkten. Meiner Meinung nach super für alle GPT Dinge. Einerseits ist gpt-3.5-turbo vom Preis/Leistungsverhältnis top, andererseits könnt Ihr – wie im unterem Script Beispiel – super über den System Input die Antwort steuern. 

Hier mal etwas zum kopieren:
 

Simpler prompt (Gedacht als Globale Funktion): (API-Key einfügen nicht vergessen)

function gptCall(prompt : text) do
    do as server
        let url := "https://api.openai.com/v1/chat/completions";
        let APIKey := "Bearer XXXX-DEIN-OPENAI-API-KEY";
        let response := http("POST", url, {
                Authorization: APIKey,
                'content-type': "application/json"
            }, {
                model: "gpt-3.5-turbo",
                messages: [{
                        role: "user",
                        content: prompt
                    }],
                temperature: 0.7,
                max_tokens: 2048
            });
        first(response.result.choices).message.content
    end
end;

Das kann dann hinter einem Button, zB. direkt so verwendet werden:
Prompt und Antwort sind Felder in meiner Tabelle.

let result := gptCall(Prompt);
Antwort := result

  Prompt mit System Input (Gedacht als Globale Funktion): (API-Key einfügen nicht vergessen)

function gptCallCustomTone(prompt : text,tone : text) do
    do as server
        let url := "https://api.openai.com/v1/chat/completions";
        let APIKey := "Bearer XXXX-DEIN-OPENAI-API-KEY";
        let response := http("POST", url, {
                Authorization: APIKey,
                'content-type': "application/json"
            }, {
                model: "gpt-3.5-turbo",
                messages: [{
                        role: "system",
                        content: tone
                    }, {
                        role: "user",
                        content: prompt
                    }],
                temperature: 0.7,
                max_tokens: 2048
            });
        first(response.result.choices).message.content
    end
end;

Und verwendet wird das wie folgt:

let result := gptCallCustomTone(Prompt, "Antworte mit Hessischen Akzent");
Antwort := result

let result := gptCallCustomTone("Das hier ist mein Kunde:"+Kontext+" Formuliere sein Business-Model", "Antworte aus der Sicht eines MBA Experten");
Antwort := result

Kann man natürlich noch für andere massiv coole Dinge nutzen, hier ein paar Beispiele für hervoragende System Inputs:

• Schreibe so, als wäre es eine Apple Key Note Präsentation
• Schreibe so, dass es ein 5 Jähriger verstehen würde
• Antwort als valides strukturiertes JSON
• Antworte aus der Sicht *Experte einfügen*

Und vieles mehr! An der Stelle ist es wirklich nur noch Prompt Engineering!

Lasst mich doch gern wissen wofür Ihr das einsetzen würdet. Ich bin immer fasziniert zu sehen was Leute mit KI machen.