Hallo Markus, meinst du so eine Art Feldmaske, bei der für jede Position vorgegeben ist, welche Art von Zeichen man dort eintippen kann? Sowas gibt es in Ninox leider nicht (ist allerdings als Change Request angefragt).

 

Man kann die Ziffern der ISBN natürlich gleich in ein Feld vom Typ Zahl eingeben. Oder mit Bindestrichen in ein Textfeld und zur Prüfung dann in einen numerischen Werte umwandeln:

 

number(replace(ISBN, "-", ""))

 

Oder geht es um eine Kontrolle anhand der Prüfziffer? Das könnte man bspw. mit einem Funktionsfeld machen (oder auf dem Mac auch als Trigger mit alert() statt styled()):

 

let myISBN := replace(ISBN, "-", "");
let myPZ := number(substr(myISBN, length(myISBN) - 1, 1));
let xSum := 0;
let ySum := 0;
for x from 0 to 11 step 2 do
    let xZiffer := number(substr(myISBN, x, 1));
    xSum := xSum + xZiffer
end;
for y from 1 to 12 step 2 do
    let yZiffer := number(substr(myISBN, y, 1)) * 3;
    ySum := ySum + yZiffer
end;
let mySum := xSum + ySum;
let myMod := ceil(mySum / 10) * 10;
let myChk := if myMod = 10 then 0 else myMod - mySum end;
let myCol := if myChk = myPZ then "Green" else "Red" end;
styled(text(myChk), myCol)

 

Wie immer gilt: Nach bestem Wissen und Gewissen, aber ohne Gewähr.

Hi, kannst Du mal schreiben, was genau Du "kontrollieren" willst? Dann ist es besser möglich mitzudenken, was Du dafür brauchst. Vielleicht gibt es einen Turnaround dafür. Zahlenfelder gehen nur mit Präfix und Einheit. Bindestriche lassen sich nicht eintragen. Jedenfalls soweit ich weiß. Du wirst also mit Textfeldern oder Funktionsfeldern arbeiten müssen, dann ist es Text. Aber Du willst ja auch nicht ISBN Nummern addieren ;-), also damit rechnen. Mirko

Ja, ich bin für das Skript davon ausgegangen, dass es ein Textfeld namens ISBN mit selbiger als Inhalt gibt. Das erschien mir am wahrscheinlichsten, denn wie Mirko richtig sagte: Die ISBN generell als Zahl zu speichern, macht im Grunde wenig Sinn, weil man ja keine mathematischen Operationen damit durchführt. In ein Textfeld könnte man bei physisch greifbaren Titeln übrigens außerdem auch den Barcode einlesen.

 

In der ersten Code-Zeile übernehme ich also den Inhalt des Textfeldes ISBN in die Variable myISBN und entferne dabei ggf. vorhandene Bindestriche. In der zweiten Zeile lese ich das letzte Zeichen mit der Prüfziffer aus, um es später (vorletzte Zeile) mit dem errechneten Wert vergleichen zu können.

 

Dann erfolgt die eigentliche Berechnung der Prüfziffer. Wie gesagt: Ohne Gewähr, aber mit einer Handvoll getesteter ISBN hat's funktioniert.

Hallo Markus, 

Du hast zwar schon eine Lösung, hier ist aber noch meine dazu. Du benötigst ein Textfeld „ISBN“ und ein Berechnungsfeld z.B. „Check“. 

Im Textfeld die Nummer ohne Bindestriche einfügen, oder meinem Code noch die Replacevariante vom Copytexter hinzufügen. Dann im Berechnungsfeld den Code einfügen:

 

let A := number(sum(for G in range(1, 13, 2) do

number(item(ISBN, G)) * 3

end));

let B := number(sum(for U in range(0, 13, 2) do

item(ISBN, U)

end));

if last(for P in range(0, 3) do

item(text(A + B), P)

end) = 0 then

true

else

false

end

 

Er nutzt die Formel für die Prüfzifferberechnung, addiert diese hinzu und checkt, ob am Ende eine 0 steht. Dann ist das Ergebnis korrekt. Korrekterweise wird die Prüfziffer bestimmt indem nur die ersten 12 Ziffern verrechnet werden und beim Ergebnis die letzte Ziffer von 10 subtrahiert wird, was die Prüfziffer ergibt. Aber so müsste es reichen für Deine Zwecke und ich hatte Spass beim Knobeln.

Mirko

Hallo Markus, ich meinte so:

let X := replace(ISBN, "-", "");
let A := number(sum(for G in range(1, 13, 2) do
number(item(X, G)) * 3
end));
let B := number(sum(for U in range(0, 13, 2) do
item(X, U)
end));
if last(for P in range(0, 3) do
item(text(A + B), P)
end) = 0 then
true
else
false
end

Im Feld "Check", oder wie Du es auch nennen willst in den Einstellungen unter "Feld nur anzeigen, wenn" trägst Du Check=false ein, damit kommt die Anzeige nur, wenn es eine falsche Nummer ist. Mirko

Hallo Markus, die bisherigen Code-Vorschläge und -Fragmente waren sehr allgemein, weil ja keine genauen Informationen zu deiner Konstellation vorlagen. Der Code-Block, den ich oben gepostet habe, war auch als Vorschlag für ein Funktionsfeld gedacht. Weil das - im Gegensatz zu alert() - so in jeder Konstellation auf jeder Plattform funktionieren sollte. Ein Texfeld mit der ISBN und ein Funktionsfeld ('Prüfziffer') mit oben stehendem Code - mehr ist nicht erforderlich, um das überhaupt erst mal zu testen.

Wenn man statt des Funktionsfeldes dann bspw. lieber eine Meldung per alert() hätte, dann muss man den Code und die Vorgehensweise halt entsprechend anpassen. Für die Variante mit alert() würde man den Code nicht in einem Funktionsfeld, sondern leicht abgewandelt als Trigger "Nach Änderung" im Textfeld 'ISBN' ausführen. Ändern würden sich (bei meinem Code) aber nur die beiden letzten Zeilen, in der das Ergebnis abgefragt und eine entsprechende Aktion ausgelöst wird:

 

[...]
if myChk != myPZ then
    alert("Falsche ISB-Nummer!")
end

 

Alles andere, also die eigentliche, mathematische Berechnung der Prüfziffer, bleibt geich. Mirkos Code ist da programmiertechnisch sogar cleverer, effizienter. Dafür etwas schwieriger zu lesen und anzupassen. Aber er, also Mirko, hilft dir sicher auch bei der Anpassung auf ein alert().

 

Du musst nur konkret danach fragen.

 

PS: Das Problem mit alert() ist, dass es im Web nicht mit Triggern und Funktionsfeldern funktioniert (nur mit Schaltflächen). Voraussetzung wäre also, dass du mit der Mac-App arbeitest. Dort geht es.

 

PPS: Das "number(replace(ISBN, ...))" war lediglich ein Beispiel dafür, wie man eine als String vorliegende ISBN in eine Zahl konvertieren könnte. Ohne konkreten Bezug. Für die Berechnung der Prüfziffer brauchst du diese Formel nicht.

Hi, Markus. G, U und P sind die "Laufindexe" der for-Schleifen. Es sind quasi nur "Platzhalter" und frei benennbar. Ich nehme für Variablen (let) und Schleifen (for..range und for...select) gern Großbuchstaben - eine Marotte von mir. Ich kann sie so besser auseinanderhalten und und es ist weniger Code. Es kann auch Probleme bringen, wenn die Benennung dadurch nicht eindeutig ist. Also, es waren zwei Variablen im Spiel A und B und 3 Laufindexe G, U und P. Übrigens benutzt Du in dem oben stehenden Code auch eine for-Schleife und hast sie "x" genannt ist nur anders deklariert als "range". Viel Spass noch mit Deinem Projekt. Mirko

Hallo Markus, bei der ISBN-10 wird die Prüfziffer halt ganz anders berechnet. Im Grunde sogar einfacher, weil alle Ziffern nach demselben Schema verarbeitet werden. Leider hat Ninox keine Rest-Funktion, den muss man selbst berechnen (Zeilen 8 und 9). Weitere Besonderheit ist das mögliche "X" als römische 10. Man vergleicht am Ende also nicht Zahlen, sondern Zeichen (Zeilen 10/11). So sollte es mit der Berechnung klappen:

 

let myISBN := replace(ISBN10, "-", "");
let myPZ := substr(myISBN, length(myISBN) - 1, 1);
let xSum := 0;
for x from 1 to 10 do
    let xZiffer := number(substr(myISBN, x - 1, 1));
    xSum := xSum + xZiffer * x
end;
let myGanzzahl := floor(xSum / 11);
let myRest := xSum - myGanzzahl * 11;
let myChk := if myRest = 10 then "X" else text(myRest) end;
let myCol := if myChk = myPZ then "Green" else "Red" end;
styled(text(myChk), myCol)

 

Anmerkungen:
Den "step"-Wert in der for-Schleife hattest du richtig auf 1 geändert. Da 1 aber der Standardwert ist, kann man ihn auch weglassen.
Der "from"-Wert in der "for"-Schleife ist inklusive, der "to"-Wert exklusive. "from 1 to 10" zählt also von 1 bis 9.
Die Zählung der Positionen bei substr() beginnt immer bei 0.

 

Um den X-Wert auch gleich als Multiplikator für jede Ziffer nutzen zu können, habe ich "from 1 to 10" angegeben und subtrahiere beim substr() immer die 1.

Nur vollständigkeitshalber: Ninox hat die Rest-Funktion. Heißt modulo und ist hier verstekt https://ninox.com/de/manual/berechnung/berechnungen-und-formeln

Leo

Aaah, das Prozentzeichen, stimmt - jetzt, wo du's sagst ... *vordiestirnklatsch*

 

Das hatte ich total vergessen (wie so vieles). Danke für die Erinnerung!

Respekt, dass du versuchst, das Skript selbst anzupassen. Nur so lernt man's ja ... ;)

 

Ich interpretiere den Code so, dass du nur ein Feld für die ISBN hast und dort, wie's gerade kommt, entweder die 10- oder die 13-stellige einträgst. Ist das richtig? Wenn ja, würde ich etwas anders vorgehen: Zuerst anhand der Länge ermitteln, um welchen ISBN-Typ es sich handelt und dann die entsprechende Berechnung ausführen:

 

if ISBN then
    let myISBN := replace(ISBN, "-", "");
    let myPZ := number(substr(myISBN, length(myISBN) - 1, 1));
    if length(myISBN) = 10 then
        "********************************************************";
        " BERECHNUNG ISBN 10 ";
        "********************************************************";
        let xSum := 0;
        for x from 1 to 10 do
            let xZiffer := number(substr(myISBN, x - 1, 1));
            xSum := xSum + xZiffer * x
        end;
        let myGanzzahl := floor(xSum / 11);
        let myRest := xSum - myGanzzahl * 11;
        let myChk := if myRest = 10 then "X" else text(myRest) end;
        let myCol := if myChk = myPZ then "Green" else "Red" end;
        styled(text(myChk), myCol)
    else
        "********************************************************";
        " BERECHNUNG ISBN 13 ";
        "********************************************************";
        let xSum := 0;
        let ySum := 0;
        for x from 0 to 11 step 2 do
            let xZiffer := number(substr(myISBN, x, 1));
            xSum := xSum + xZiffer
        end;
        for y from 1 to 12 step 2 do
            let yZiffer := number(substr(myISBN, y, 1)) * 3;
            ySum := ySum + yZiffer
        end;
        let mySum := xSum + ySum;
        let myMod := ceil(mySum / 10) * 10;
        let myChk := if myMod = 10 then 0 else myMod - mySum end;
        let myCol := if myChk = myPZ then "Green" else "Red" end;
        styled(text(myChk), myCol)
    end
end

hi Markus, hi Copytexter. Ein tolles Projekt von Euch, woraus ich viel gelernt habe. Sehr cool und danke. Es wäre auch gut geeignet in den Praxisbeispielen der Ninox-Referenz zu stehen. Nur mal so gesagt. Danke Leo für den Hinweis auf die Moduloberechnung. Das habe ich wohl überlesen. Mirko

Hallo Mirko, dein Code zu Berechnung der Prüfziffer ist programmiertechnisch wie gesagt sogar besser, kompakter als meiner. Ehre, wem Ehre gebührt. Ich bin in den weiteren Erläuterungen nur bei meinem Code geblieben, weil er für den Einstieg wahrscheinlich etwas besser lesbar ist und ich nichts durcheinanderbringen wollte.

 

Was die Referenz betrifft: Zufälligerweise wurde gerade vor zehn Minuten eine neue Version der Referenz-DB ins Webinar-Team eingestellt. Sie wurde von Uwe G. um die Möglichkeit ergänzt, die Beschreibungstexte in verschiedenen Sprachen abzulegen und heißt jetzt "0001_Reference_ML". Inhaltlich hat sich sonst nichts geändert. Diese ISBN-Geschichte ist ja schon recht speziell, aber du kannst sie gerne bei den Praxisbeispielen eintragen. So, wie du es für richtig hältst.

 

Und wer Lust hat, darf sich natürlich auch gerne an den Übersetzungen beteiligen. ;)

@Markus: leider rechnet dein Code die 13stelligen ISBN nicht korrekt, es gab einige Fehler bei meinen Proben. Falls du ihn, so wie hier veröffentlicht in Benutzung hast, dann wäre eine Korrektur nötig.

@Copytexter: funktioniert perfekt bis auf rotes „X“, was ja Markus schon geschrieben hat.

Vielleicht ist ja auch schon alles korrigiert und funktioniert prächtig, trotzdem hier noch meine Version und nur der Vollständigkeit halber, die auf der Plausibilitätsrechnung der ISBN (50 Fälle) beruht, also alle 10 oder 13 stelligen ISBN einbezieht und deren Ergebnis „0“ ergeben muß. Das macht es möglich, dass man das Feld verstecken kann und nur dann angezeigt bekommt, wenn das Ergebnis !=0 ist. Tricky war die Einbindung der 10er Ziffern mit X, deshalb die verschachtelten „if“. Danke an Copytexter für replace und length und an Leo für modulo und Markus für die Aufgabe. Ich wollte es nur abschliessen für den unwahrscheinlichen Fall, dass jemand noch mal ISBN-Nummer checken will ;-)

Mirko

Feld 1: Textfeld: "ISBN"

Feld 2: Funktionsfeld "Check", Beschriftungsposition: versteckt, Feld nur anzeigen, wenn: Check = "", Stil Textbox: fett, groß

let X := replace(ISBN, "-", "");
let Z := for Q in range(0, 10) do
item(X, Q)
end;
if if length(X) = 10 then
if last(Z) = "X" then
(sum(for U in range(0, 9) do
number(item(X, U)) * (U + 1)
end) + 100) % 11
else
sum(for U in range(0, 10) do
number(item(X, U)) * (U + 1)
end) % 11
end
else
let A := number(sum(for G in range(1, 13, 2) do
number(item(X, G)) * 3
end));
let B := number(sum(for U in range(0, 13, 2) do
item(X, U)
end));
(A + B) % 10
end != 0 then
""
end

Und hier noch für die, die ISBN frühstücken, die Berechnung der Prüfziffer.

let X := replace(ISBN, "-", "");
let Y := if length(X) = 10 then
sum(for U in range(0, 9) do
number(item(ISBN, U)) * (U + 1)
end) % 11
else
let A := number(sum(for G in range(1, 12, 2) do
number(item(X, G)) * 3
end));
let B := number(sum(for U in range(0, 12, 2) do
item(X, U)
end));
(10 - (A + B) % 10) % 10
end;
if Y = 10 then "X" else text(Y) end