Hi Tholio ,

Eigentlich stellt sich in der Ninox-Vorlage im Drucklayout für Angebote/Rechnungen je nach TYP alles automatisch um auf Angebot/Rechnung/Lieferschein.
Wenn Du es wirklich separat haben willst, würde ich so vorgehen:

1. den bestehenden PDF-Button umbenennen in z.B. "Angebots-PDF"
2. ein neues Bildfeld einfügen und dieses "Angebot" nennen
3. einen neuen Button einfügen (Layout-Elemente)
   und diesen z.B. "Rechnungs-PDF" nennen.
4. der Angebotsbutton braucht ein Skript mit Erkennung ob TYP= Angebot oder Lieferschein. Danach erst wird der Befehl zum PDF-Generieren ausgeführt.
   Hier legst Du fest, welches Layout "gedruckt" werden soll
    

Mit diesem Skript für den Button "Angebots-PDF" sollte das gewünschte herauskommen:
in den Annahme, dass TYP = 1 Angebot ist usw.

if number(Typ) = 1 or number(Typ) = 3 then
    let myFileName := "Angebot_" + 'ID-Nr' + "_vom_" + format(today(), "YYYY-MM-DD") + ".pdf";
    importFile(this, printAndSaveRecord(this, "Angebot/Lieferschein"), myFileName);
    Angebot := myFileName
end

der Rechnungs Button bekommt dann dieses Skript:

if number(Typ) = 2 then
    let myFileName := "Rechnung_" + 'ID-Nr' + "_vom_" + format(if 'Datum der Rechnungsstellung' then
            'Datum der Rechnungsstellung'
        else
            today()
        end, "YYYY-MM-DD") + ".pdf";
    importFile(this, printAndSaveRecord(this, "Rechnung"), myFileName);
    Rechnung := myFileName
end

(Zusätzlich kannst Du den Angebotsbutton und das Bildfeld Angebot nur einblenden, wenn TYP = 1 oder 3 oder ist und entsprechend bei TYP=2 nur Rechnungsbutton und Bildfeld einblenden). Das geht bei den Feldeigenschaften "Feld nur anzeigen wenn"

Viel Erfolg
Ronald
 

War schon mal Thema vor ein paar Tagen hier und hat Planox beantwortet. Im Druck-Editor für die Rechnungsvorlage ist ein Bug. Das Feld "Vielen Dank für Ihre Bestellung...blabla" muss direkt im Editor geändert werden. Dort sind die Typen falsch hinterlegt. Da steht fälschlich 7 oder 8 und nicht 1 oder 3. Also doppelklicken in das Feld und folgenden Code eintragen:

if not (Typ = 1 or Typ = 3) then
    "Vielen Dank für Ihre Bestellung vom " + 'Datum der Rechnungsstellung' + ". Wir erwarten den Zahlungseingang bis zum " + switch Zahlungsziel do
    case 1:
        'Datum der Rechnungsstellung' + 7
    case 2:
        'Datum der Rechnungsstellung' + 14
    case 3:
        date(year('Datum der Rechnungsstellung'), month('Datum der Rechnungsstellung') + 1, day('Datum der Rechnungsstellung'))
    case 4:
        date(year('Datum der Rechnungsstellung'), month('Datum der Rechnungsstellung') + 3, day('Datum der Rechnungsstellung'))
    case 5:
        date(year('Datum der Rechnungsstellung') + 1, month('Datum der Rechnungsstellung'), day('Datum der Rechnungsstellung'))
    case 6:
        'Datum der Rechnungsstellung' + 'individuelles Zahlungsziel (Tage)'
    default:
        'Datum der Rechnungsstellung' + 30
    end + "."
end

und speichern nicht vergessen;-)

...achso, und das gleiche noch ändern oben links neben Datum die Rechnungs-, Angebots-, Lieferscheinnummern